从网页启动桌面应用程序

2015/05/10 39804
@echo off
rem @20131105
rem author:邓有权
rem email:youquan.deng@gmail.com
rem 设置窗口title
title 网页启动桌面程序
echo 自定义协议开始执行...
echo. 
echo 1.必要准备...
echo.
rem 设置可执行程序的路径
set exepath=nul
:setexe
set /p exepath=请输入要启动的exe文件全路径(路径用英文双引号引起)：
echo.
rem 判断全路径是否为空 是否存在
if %exepath% NEQ nul (
    echo 您输入的exe文件全路径为： %exepath%
    echo.
    echo 检查exe文件是否存在...
    if exist %exepath% (
	echo exe文件存在
    ) else (
	echo exe文件不存在，请确认后重新输入 
	goto setexe
    )
) else (
    echo exe文件全路径不能为空，请重新输入
    goto setexe
)
echo.
if %ERRORLEVEL% EQU 0 (
    echo 准备完成
) else (
    echo 准备失败，请与作者联系
    pause
    exit
)
echo.
echo 2.正式执行...
rem @echo on
rem REG ADD HKCR\lkpower /f
REG ADD HKCR\lkpower /f /d "URL: Lkpower OA 协议"
REG ADD HKCR\lkpower /f /v "URL Protocol"

rem REG ADD HKCR\lkpower\DefaultIcon /f
REG ADD HKCR\lkpower\DefaultIcon /f /t REG_SZ /d %exepath%,1

rem REG ADD HKCR\lkpower\shell /f
rem REG ADD HKCR\lkpower\shell\open /f
rem REG ADD HKCR\lkpower\shell\open\command /f
REG ADD HKCR\lkpower\shell\open\command /f /d "%exepath:"=% LIMS_DATA,LIMS_DICT"
rem @echo off
echo.
if %ERRORLEVEL% EQU 0 (
    echo 执行成功
) else (
    echo 执行不成功，请与作者联系
)
echo.
pause
代码片段
